/* Betätigungsdauer Taster erkennen
 */
#include <MobaTools.h>
 
EggTimer Prellzeit;
const int entprellZeit = 20; // in ms
const byte warteZeit = 100;  // = 2sek, in Entprellzeit-Einheiten
int warteZaehler;            // Zaehler für die Länge des Tastendrucks
bool tasterStatus = HIGH;    // aktueller Tasterstatus
const byte tasterPin = 12;
 
void setup() {
    Serial.begin( 115200 );
    pinMode( tasterPin, INPUT_PULLUP );
    Prellzeit.setTime( entprellZeit );
}
 
void loop() {
    // Länge eines Tastendruckes auswerten
    if ( ! Prellzeit.running() ) {
        // Taster nur alle 20ms ( Entprellzeit ) abfragen 
        Prellzeit.setTime( entprellZeit );
        warteZaehler ++;
        // Taster abfragen
        if ( tasterStatus != digitalRead( tasterPin ) ) {
            //Flankenwechsel am Taster
            if ( tasterStatus == HIGH ) {
                // Taste wurde gedrückt, Zeit starten
                warteZaehler = 0;
                tasterStatus = LOW;
            } else {
                // Taste wurde losgelassen, auswerten
                tasterStatus = HIGH;
                if ( warteZaehler < warteZeit ) {
                    Serial.println("kurz gedrückt");
                } else {
                    Serial.println("lang gedrückt");
                }
            }
        }
    }
    // hier kann beliebiger weiterer Code stehen, der ständig im loop abgearbeitet wird
}